PK火游戏排行榜

标题: BLUE引擎 传奇挑战擂台脚本源码教程 [打印本页]

作者: pkhuo    时间: 2021-9-30 20:56
标题: BLUE引擎 传奇挑战擂台脚本源码教程
[@加载Bluem2.net_挑战擂台QM]
{
[@OnTimer12]
#IF
ISONMAP BLUETZ
#ELSEACT
KillScTimer 12
BREAK
#IF
CHECKLEVELEX > 0
#ACT
MOV S68


#IF
checkvar GLOBAL 挑战邀请姓名 = <$USERNAME>
#ACT
MOV S68 Bluem2.net
#IF
checkvar GLOBAL 挑战发起姓名 = <$USERNAME>
#ACT
MOV S68 Bluem2.net

#IF
checkvar GLOBAL 挑战开始判断 < 2
#ACT
MOV S68
#IF
EQUAL S68
CheckInMapRange BLUETZ 16 19 5
#ACT
MAPMOVE 3 330 330
BREAK
#IF
EQUAL S68
#ACT
BREAK
#IF
CheckInMapRange BLUETZ 16 19 5
#ELSEACT
MAPMOVE 3 330 330
SENDMSG 6 由于您移动到光环外,系统判您输掉本次挑战!
MESSAGEBOX 由于您移动到光环外,系统判您输掉本次挑战!
BREAK


[@挑战擂台清理场地]
#IF
CheckInMapRange BLUETZ 16 19 5
#ACT
MAPMOVE 3 330 330
BREAK

[@挑战擂台邀请响应]
#IF
CheckStringList ..\QuestDiary\Bluem2.net_挑战擂台配置\禁止弹出提示地图.txt <$CURRENTMAP>
#ACT
BREAK
#IF
EQUAL D68 0
#ACT
break
#IF
checkvar human 挑战个人开启 = 关闭
#ELSEACT
DELAYGOTO 1 @挑战擂台脚本NPC








[@挑战擂台脚本NPC]
#IF
CHECKLEVELEX > 0
#ACT
CALCVAR HUMAN 挑战个人开启 =
#IF
checkvar GLOBAL 挑战开始判断 = 1
#SAY
    <COLOR=$0079FF 〝≈><COLOR=$00A0FF 傲><COLOR=$00B1FF 世><COLOR=$00C2FF 傳><COLOR=$00D3FF 奇><COLOR=$00B1FF ≈><COLOR=$00FFC5 正版><COLOR=$00FFD6 授权><COLOR=$00FFE7 ≈><COLOR=$00FFF8 公司><COLOR=$00F5FF 运营><COLOR=$00E4FF ≈><COLOR=$00D3FF 独><COLOR=$00C2FF 家><COLOR=$00B1FF 奉><COLOR=$00A0FF 献><COLOR=$0079FF ≈〞>\
<COLOR=$00393942 ─────────────────────────────>\
<COLOR=$EE82EE 地图光圈内剩余1人时即可领取获胜奖励:><$GLOBAL(挑战发起数量)><COLOR=$EE82EE 元宝>\
<COLOR=$00FFCC 如果 $(挑战擂台进行时间)分钟 内不分胜负,双方均视为挑战失败!>\
<COLOR=CLRED 挑战地图禁止喝药.魔血石无效!光圈外为安全区域,其他玩家可观战.>\
<COLOR=CLRED 参赛者移动出光环外或观战者移动入光环内均传回土城.>\ \
玩家 <$GLOBAL(挑战发起姓名)> 向 <$GLOBAL(挑战邀请姓名)> 发起了擂台邀请.倒计时:<$GLOBAL(挑战开始计时)>秒\ \
<[接受挑战]/@挑战擂台邀请响应接受>       <[拒绝挑战]/@挑战擂台邀请响应拒绝>       <[进入观战]/@挑战擂台邀请响应观战>       <[关闭接收]/@挑战擂台关闭接收>




#ACT
BREAK

#IF
checkvar GLOBAL 挑战开始判断 = 0
#SAY
    <COLOR=$0079FF 〝≈><COLOR=$00A0FF 傲><COLOR=$00B1FF 世><COLOR=$00C2FF 傳><COLOR=$00D3FF 奇><COLOR=$00B1FF ≈><COLOR=$00FFC5 正版><COLOR=$00FFD6 授权><COLOR=$00FFE7 ≈><COLOR=$00FFF8 公司><COLOR=$00F5FF 运营><COLOR=$00E4FF ≈><COLOR=$00D3FF 独><COLOR=$00C2FF 家><COLOR=$00B1FF 奉><COLOR=$00A0FF 献><COLOR=$0079FF ≈〞>\
<COLOR=$00393942 ─────────────────────────────>\
<COLOR=$FF901E 玩家可在此处申请挑战 [指定勇士] 或 [全服任意一勇士]>\
<COLOR=$EE82EE 地图光圈内剩余1人时即可领取获胜奖励!>\
<COLOR=$00FFCC 如果 $(挑战擂台进行时间)分钟 内不分胜负,双方均视为挑战失败!>\
<COLOR=CLRED 挑战地图禁止喝药.魔血石无效!光圈外为安全区域,其他玩家可观战.>\
<COLOR=CLRED 参赛者移动出光环外或观战者移动入光环内均传回土城.>\
<[挑战玩家设置]/@挑战擂台输入名字>:<$HUMAN(挑战个人姓名)>\
<[擂台元宝设置]/@挑战擂台输入数量>:<$HUMAN(挑战个人数量)>\
<[确定开设擂台]/@挑战擂台发起确定>                             <[进入擂台观战]/@挑战擂台邀请响应观战>

#ACT
BREAK
#ELSEACT
MOV D10 0

#IF
CHECKONLINE <$GLOBAL(挑战发起姓名)>
<$GLOBAL(挑战发起姓名)>.ISONMAP BLUETZ
#ELSEACT
INC D10 1
#IF
CHECKONLINE <$GLOBAL(挑战邀请姓名)>
<$GLOBAL(挑战邀请姓名)>.ISONMAP BLUETZ
#ELSEACT
INC D10 1

#IF
LARGE D10 1
#ACT
CALCVAR GLOBAL 挑战发起姓名 =
CALCVAR GLOBAL 挑战邀请姓名 =
CALCVAR GLOBAL 挑战发起数量 = 0
CALCVAR GLOBAL 挑战开始计时 = 0
CALCVAR GLOBAL 挑战开始判断 = 0
SAVEVAR GLOBAL 挑战发起姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战邀请姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战发起数量 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始计时 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始判断 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SENDMSG 0 $(挑战擂台公告前缀)挑战双方已离开挑战地图,均视为挑战失败!
DELAYGOTO 1 @挑战擂台脚本NPC
BREAK
#ELSEACT
MOV D11 <$GLOBAL(挑战开始计时)>
MOV D12 <$GLOBAL(挑战开始计时)>
DIV D11 60
MOV D10 <$STR(D11)>
MUL D10 60
DEC D12 <$STR(D10)>
BREAK
#ELSESAY
    <COLOR=$0079FF 〝≈><COLOR=$00A0FF 傲><COLOR=$00B1FF 世><COLOR=$00C2FF 傳><COLOR=$00D3FF 奇><COLOR=$00B1FF ≈><COLOR=$00FFC5 正版><COLOR=$00FFD6 授权><COLOR=$00FFE7 ≈><COLOR=$00FFF8 公司><COLOR=$00F5FF 运营><COLOR=$00E4FF ≈><COLOR=$00D3FF 独><COLOR=$00C2FF 家><COLOR=$00B1FF 奉><COLOR=$00A0FF 献><COLOR=$0079FF ≈〞>\
<COLOR=$00393942 ─────────────────────────────>\
<COLOR=$EE82EE 地图光圈内剩余1人时即可领取获胜奖励:><$GLOBAL(挑战发起数量)><COLOR=$EE82EE 元宝>\
<COLOR=$00FFCC 挑战擂台正在进行.....倒计时:> <$STR(D11)>分<$STR(D12)>秒\
<COLOR=CLRED 挑战地图禁止喝药.魔血石无效!光圈外为安全区域,其他玩家可观战.>\
<COLOR=CLRED 参赛者移动出光环外或观战者移动入光环内均传回土城.>\ \
挑战擂台发起玩家:<$GLOBAL(挑战发起姓名)>\
挑战擂台响应玩家:<$GLOBAL(挑战邀请姓名)>\
<[领取擂台奖励]/@挑战擂台领取奖励>                             <[进入擂台观战]/@挑战擂台邀请响应观战>





[@挑战擂台领取奖励]
#IF
checkvar GLOBAL 挑战开始判断 < 2
#ACT
MESSAGEBOX 对不起,挑战已经结束!
break
#ELSEACT
MOV S10
#IF
checkvar GLOBAL 挑战邀请姓名 = <$USERNAME>
#ACT
MOV S10 <$GLOBAL(挑战发起姓名)>
#IF
checkvar GLOBAL 挑战发起姓名 = <$USERNAME>
#ACT
MOV S10 <$GLOBAL(挑战邀请姓名)>
#IF
EQUAL S10
#ACT
MESSAGEBOX 对不起,您不是挑战者!
BREAK
#IF
CheckInMapRange BLUETZ 16 19 5
#ELSEACT
MESSAGEBOX 对不起,您已经离开光环范围,无法领取!
BREAK
#IF
CHECKONLINE <$STR(S10)>
<$STR(S10)>.CheckInMapRange BLUETZ 16 19 5
#ACT
SENDMSG 6 请将对手清理出光环外才能领取奖励!
close
BREAK

#IF
CHECKLEVELEX > 0
#ACT
MOV D9 <$GLOBAL(挑战发起数量)>
MOV S11
#IF
checkvar GLOBAL 挑战发起数量 > 20000000
#ACT
MOV D8 <$GLOBAL(挑战发起数量)>
DIV D8 100
MUL D8 $(挑战擂台纳税比例)
#ELSEACT
MOV D8 <$GLOBAL(挑战发起数量)>
MUL D8 $(挑战擂台纳税比例)
DIV D8 100

#IF
LARGE D8 0
#ACT
DEC D9 <$STR(D8)>
MOV S11 (已扣除$(挑战擂台纳税比例)%共
INC S11 <$STR(D8)>
INC S11 元宝税金)

#IF
CHECKLEVELEX > 0
#ACT
GAMEGOLD + <$GLOBAL(挑战发起数量)>
GAMEGOLD + <$STR(D9)>
SENDMSG 0 $(挑战擂台公告前缀)恭喜【<$USERNAME>】挑战胜利赢取【<$STR(S10)>】的【<$STR(D9)>元宝】<$STR(S11)>!
CALCVAR GLOBAL 挑战发起姓名 =
CALCVAR GLOBAL 挑战邀请姓名 =
CALCVAR GLOBAL 挑战发起数量 = 0
CALCVAR GLOBAL 挑战开始计时 = 0
CALCVAR GLOBAL 挑战开始判断 = 0
SAVEVAR GLOBAL 挑战发起姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战邀请姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战发起数量 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始计时 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始判断 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
MAPMOVE 3 330 330
MESSAGEBOX 恭喜您,挑战胜利赢取【<$STR(S10)>】的【<$STR(D9)>元宝】!\ \<$STR(S11)>
BREAK



[@挑战擂台输入全服]
#ACT
CALCVAR HUMAN 挑战个人姓名 = $(挑战全服玩家姓名)
goto @挑战擂台脚本NPC

[@挑战擂台输入数量]
#ACT
QUERYVALUE 10 1 14 @挑战擂台输入数量2 请输入您要押注的元宝数量:(最小$(挑战押注元宝最小),最大$(挑战押注元宝最大)) QM

[@挑战擂台输入数量2]
#IF
SMALL M10 $(挑战押注元宝最小)
#ACT
MESSAGEBOX 对不起,最小需要输入$(挑战押注元宝最小)元宝!
break
#IF
LARGE M10 $(挑战押注元宝最大)
#ACT
MESSAGEBOX 对不起,最多只能输入$(挑战押注元宝最大)元宝!
break
#IF
CHECKGAMEGOLD < <$STR(M10)>
#ACT
MESSAGEBOX 对不起,您身上的元宝数量不足<$STR(M10)>个!
BREAK
#ELSEACT
CALCVAR HUMAN 挑战个人数量 = <$STR(M10)>
goto @挑战擂台脚本NPC

[@挑战擂台输入名字]
#ACT
QUERYVALUE 11 0 14 @挑战擂台输入名字2 请输入您要挑战的玩家名字(挑战全服任意玩家请输入0) QM

[@挑战擂台输入名字2]
#IF
EQUAL S11 0
#ACT
CALCVAR HUMAN 挑战个人姓名 = $(挑战全服玩家姓名)
goto @挑战擂台脚本NPC
BREAK
#IF
EQUAL S11 <$USERNAME>
#act
MESSAGEBOX 对不起,不能输入自己的名字!
BREAK
#IF
CHECKONLINE <$STR(S11)>
#ELSEACT
MESSAGEBOX 对不起,玩家【<$STR(S11)>】不在线,请确认名字是否正确!
BREAK
#ACT
CALCVAR HUMAN 挑战个人姓名 = <$STR(S11)>
goto @挑战擂台脚本NPC

[@挑战擂台发起确定]
#IF
CHECKLEVELEX > 0
#ACT
delaygoto 1 @挑战擂台脚本NPC
#IF
checkvar human 挑战个人数量 < $(挑战押注元宝最小)
#ACT
MESSAGEBOX 对不起,最小需要输入$(挑战押注元宝最小)元宝!
break
#IF
checkvar human 挑战个人数量 > $(挑战押注元宝最大)
#ACT
MESSAGEBOX 对不起,最多只能输入$(挑战押注元宝最大)元宝!
break
#IF
CHECKGAMEGOLD < <$HUMAN(挑战个人数量)>
#ACT
MESSAGEBOX 对不起,您身上的元宝数量不足<$HUMAN(挑战个人数量)>个!
BREAK

#IF
checkvar human 挑战个人姓名 = <$USERNAME>
#ACT
MESSAGEBOX 对不起,不能输入自己的名字!
BREAK
#ELSEACT
MOV S10 Bluem2.net

#IF
checkvar human 挑战个人姓名 =
#ACT
CALCVAR HUMAN 挑战个人姓名 = $(挑战全服玩家姓名)
#IF
checkvar human 挑战个人姓名 = $(挑战全服玩家姓名)
#ACT
MOV S10

#IF
CHECKONLINE <$HUMAN(挑战个人姓名)>
#ACT
MOV S10

#IF
EQUAL S10
#ELSEACT
MESSAGEBOX 对不起,玩家【<$HUMAN(挑战个人姓名)>】不在线,请确认名字是否正确!
BREAK

#IF
checkvar GLOBAL 挑战发起姓名 = <$USERNAME>
#act
MESSAGEBOX 对不起,您已经发起挑战,请勿重复提交!
break
#IF
checkvar GLOBAL 挑战发起姓名 =
#ACT
CALCVAR GLOBAL 挑战发起姓名 = <$USERNAME>
CALCVAR GLOBAL 挑战邀请姓名 = <$HUMAN(挑战个人姓名)>
CALCVAR GLOBAL 挑战发起数量 = <$HUMAN(挑战个人数量)>
CALCVAR GLOBAL 挑战开始计时 = $(挑战擂台响应时间)
CALCVAR GLOBAL 挑战开始判断 = 1
SAVEVAR GLOBAL 挑战发起姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战邀请姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战发起数量 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始计时 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始判断 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SENDMSG 0 $(挑战擂台公告前缀)【<$USERNAME>】向【<$HUMAN(挑战个人姓名)>】发起了擂台邀请 251 0
MESSAGEBOX 发起成功,请等待【<$HUMAN(挑战个人姓名)>】回应...
Gmexecute $(挑战全服触发命令) @挑战擂台邀请响应
#ELSEACT
MESSAGEBOX 对不起,当前已有玩家挑战,请等待结束或进入观战!
BREAK


[@挑战擂台关闭接收]
#ACT
CALCVAR HUMAN 挑战个人开启 = 关闭
SENDMSG 6 $(挑战擂台公告前缀)你已关闭接受挑战信息!需重新开启请点击NPC!
close

[@挑战擂台邀请响应观战]
#IF
CHECKSLAVECOUNT > 0
#ACT
QUERYVALUE 0 2 0 @挑战擂台邀请响应观战B 本地图禁止携带宝宝进入,是否清理您的宝宝? QM
BREAK
#ELSEACT
goto @挑战擂台邀请响应观战B

[@挑战擂台邀请响应观战B]
#IF
ISONMAP BLUETZ
#ACT
MESSAGEBOX 你已在挑战擂台地图!
break
#IF
CHECKHEROONLINE
#ACT
MESSAGEBOX 对不起,本地图禁止携带英雄进入!
break
#IF
checkvar GLOBAL 挑战开始判断 > 1
checkvar GLOBAL 挑战邀请姓名 = <$USERNAME>
#ACT
MESSAGEBOX 对不起,您是挑战者,挑战期间不能进行围观!
break
#IF
checkvar GLOBAL 挑战开始判断 > 1
checkvar GLOBAL 挑战发起姓名 = <$USERNAME>
#ACT
MESSAGEBOX 对不起,您是挑战者,挑战期间不能进行围观!
break
#IF
CHECKSLAVECOUNT > 0
#ACT
KILLSLAVE self <$CURRENTX> <$CURRENTY> 100 * 100 0
#IF
CHECKSLAVECOUNT > 0
#ACT
MESSAGEBOX 对不起,清理宝宝失败,请将您的宝宝召唤到身边再点确定!
break
#IF
CHECKLEVELEX > 0
#ACT
MAPMOVE BLUETZ 24 24
SetScTimer 12 1

[@挑战擂台邀请响应拒绝]
#IF
checkvar GLOBAL 挑战开始判断 = 1
#ELSEACT
close
BREAK
#IF
checkvar GLOBAL 挑战邀请姓名 = <$USERNAME>
#ACT
SENDMSG 0 $(挑战擂台公告前缀)【<$GLOBAL(挑战邀请姓名)>】拒绝了【<$GLOBAL(挑战发起姓名)>】的挑战! 25 0
<$GLOBAL(挑战发起姓名)>.MESSAGEBOX 对不起,【<$GLOBAL(挑战邀请姓名)>】拒绝接受您的挑战!
CALCVAR GLOBAL 挑战发起姓名 =
CALCVAR GLOBAL 挑战邀请姓名 =
CALCVAR GLOBAL 挑战发起数量 = 0
CALCVAR GLOBAL 挑战开始计时 = 0
CALCVAR GLOBAL 挑战开始判断 = 0
SAVEVAR GLOBAL 挑战发起姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战邀请姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战发起数量 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始计时 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始判断 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
#ELSEACT
close
break

[@挑战擂台邀请响应接受]
#IF
checkvar GLOBAL 挑战发起姓名 = <$USERNAME>
#act
MESSAGEBOX 对不起,您是挑战发起者,不能响应!
break
#IF
checkvar GLOBAL 挑战开始判断 = 0
#ACT
MESSAGEBOX 对不起,该挑战已经结束!
close
BREAK
#IF
checkvar GLOBAL 挑战开始判断 > 1
#ACT
MESSAGEBOX 对不起,该挑战已经有人响应,您可选择进入观战!
BREAK
#ELSEACT
MOV S10

#IF
checkvar GLOBAL 挑战邀请姓名 = $(挑战全服玩家姓名)
#ACT
MOV S10 Bluem2.net
#IF
checkvar GLOBAL 挑战邀请姓名 = <$USERNAME>
#ACT
MOV S10 Bluem2.net

#IF
EQUAL S10
#ACT
MESSAGEBOX 对不起,该挑战只邀请玩家【<$GLOBAL(挑战邀请姓名)>】!\ \您可选择进入观战!
BREAK
#IF
CHECKGAMEGOLD < <$GLOBAL(挑战发起数量)>
#ACT
MESSAGEBOX 对不起,您身上的元宝数量不足<$GLOBAL(挑战发起数量)>个!
BREAK
#IF
CHECKONLINE <$GLOBAL(挑战发起姓名)>
#ELSEACT
MESSAGEBOX 对不起,擂主【<$GLOBAL(挑战发起姓名)>】已经下线!\ \请稍后再试!
BREAK
#IF
<$GLOBAL(挑战发起姓名)>.CHECKGAMEGOLD < <$GLOBAL(挑战发起数量)>
#ACT
<$GLOBAL(挑战发起姓名)>.MESSAGEBOX 对不起,您的元宝数量已不足<$GLOBAL(挑战发起数量)>个!\ \对方无法接受挑战,请勿将元宝转走!
MESSAGEBOX 对不起,擂主【<$GLOBAL(挑战发起姓名)>】的元宝数量已不足<$GLOBAL(挑战发起数量)>个!\ \请告知其将元宝转回再接受挑战!
BREAK
#ELSEACT
Gmexecute $(挑战全服触发命令) @挑战擂台清理场地
CALCVAR GLOBAL 挑战邀请姓名 = <$USERNAME>
CALCVAR GLOBAL 挑战开始计时 = $(挑战擂台进行时间)
CALCVAR GLOBAL 挑战开始计时 * 60
CALCVAR GLOBAL 挑战开始判断 = 2
SAVEVAR GLOBAL 挑战开始判断 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战邀请姓名 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
SAVEVAR GLOBAL 挑战开始计时 ..\QuestDiary\开区清空文本\Bluem2.net_挑战擂台全局.txt
GAMEGOLD - <$GLOBAL(挑战发起数量)>
CHANGEATTACKMODE 3
SENDMSG 6 挑战正式开始,请勿移动到光环外,否则判您输掉本次挑战!
<$GLOBAL(挑战发起姓名)>.GAMEGOLD - <$GLOBAL(挑战发起数量)>
<$GLOBAL(挑战发起姓名)>.CHANGEATTACKMODE 3
<$GLOBAL(挑战发起姓名)>.SENDMSG 6 挑战正式开始,请勿移动到光环外,否则判您输掉本次挑战!
MAPMOVE BLUETZ 20 23
SetScTimer 12 1
<$GLOBAL(挑战发起姓名)>.MAPMOVE BLUETZ 12 15
<$GLOBAL(挑战发起姓名)>.SetScTimer 12 1
BREAK

[@挑战擂台常量加载]
#CALL [\Bluem2.net_挑战擂台配置\挑战擂台常量.ini] @挑战擂台常量
}






作者: hzdj55    时间: 2022-1-10 20:32
楼主发贴辛苦了,谢谢楼主分享!我觉得PK火源码基地是注册对了!
作者: guangyi886    时间: 2022-3-20 14:05
66666666666666666
作者: akenyc    时间: 2022-5-28 19:06

楼主太厉害了!楼主,I*老*虎*U!我觉得PK火源码基地真是个好地方!
作者: snkvip    时间: 2022-8-1 22:12

楼主发贴辛苦了,谢谢楼主分享!我觉得PK火源码基地是注册对了!




欢迎光临 PK火游戏排行榜 (https://pkhuo.com/) Powered by Discuz! X3.4